<%
Option Explicit
Response.Expires = -1440

Dim iError

'Debug
'Response.Write("<pre>" & ArmarTexto() & "</pre>")
'Response.End()

'Acciones

On Error Resume Next
Call EnviarMail()
Response.Redirect("envio_fin.asp?E=" & Err.Number)

'Procedimientos

Sub EnviarMail()
	Dim oSmtpMail
	Set oSmtpMail = Server.CreateObject("Jmail.SmtpMail")
		With oSmtpMail
			.ServerAddress = "ms3-Urano.Pla.net.PY"
			.SenderName = "Postmaster"
			.Sender = "postmaster@camacoes.org.py"
			.AddRecipient "camacoes@camacoes.org.py"
			.Subject = "Solicitud de Alta de Asociado"
			.Body = ArmarTexto()
			.Execute
			.Close
		 End With
	Set oSmtpMail = Nothing
End Sub

'Funciones

Function ArmarTexto()
	Dim sBody  
	If Trim(Request.Form("TipoForm")) = "PersonaFisica" Then 
		sBody = "SOLICITUD DE SUSCRIPCIÓN (Persona Física)" & vbNewLine
		sBody = sBody & String(50, "-") & vbNewLine & vbNewLine
		sBody = sBody & WriteLine("Nombre", Trim(Request.Form("Nombre")))
		sBody = sBody & WriteLine("DNI", Trim(Request.Form("DNI")))
		sBody = sBody & WriteLine("Nacionalidad", Trim(Request.Form("Nacion")))
		sBody = sBody & WriteLine("Fecha de Nacimiento", Trim(Request.Form("FechaNac")))
		sBody = sBody & WriteLine("Lugar de Nacimiento", Trim(Request.Form("PaisNac")))
		sBody = sBody & WriteLine("Dirección", Trim(Request.Form("Domi")))
		sBody = sBody & WriteLine("Ciudad", Trim(Request.Form("Loca")))
		sBody = sBody & WriteLine("Departamento", Trim(Request.Form("Provin")))
		sBody = sBody & WriteLine("País", Trim(Request.Form("Pais")))
		sBody = sBody & WriteLine("Teléfono", Trim(Request.Form("Tel")))
		sBody = sBody & WriteLine("Fax", Trim(Request.Form("Fax")))
		sBody = sBody & WriteLine("Email", Trim(Request.Form("Mail")))
		sBody = sBody & WriteLine("Lugar de Trabajo", Trim(Request.Form("RazonSocial")))
		sBody = sBody & WriteLine("Web", Trim(Request.Form("WebSite")))
		sBody = sBody & WriteLine("Cargo", Trim(Request.Form("Cargo")))
		sBody = sBody & WriteLine("Antigúedad", Trim(Request.Form("Anti")))
		sBody = sBody & WriteLine("Actividad en la Empresa", Trim(Request.Form("ActiEmpre")))
		sBody = sBody & WriteLine("Socio que lo presenta (1)", Trim(Request.Form("Socio1")))
		sBody = sBody & WriteLine("Socio que lo presenta (2)", Trim(Request.Form("Socio2")))
		sBody = sBody & WriteLine("Socio que lo presenta (3)", Trim(Request.Form("Socio3")))
	Else 
		sBody = "SOLICITUD DE SUSCRIPCIÓN (Persona Juridica)" & vbNewLine
		sBody = sBody & String(50, "-") & vbNewLine & vbNewLine
		sBody = sBody & WriteLine("Razón Social", Trim(Request.Form("RazonSocial")))
		sBody = sBody & WriteLine("RUC", Trim(Request.Form("NIF")))
		sBody = sBody & WriteLine("Dirección", Trim(Request.Form("Domi")))
		sBody = sBody & WriteLine("Ciudad", Trim(Request.Form("Loca")))
		sBody = sBody & WriteLine("Departamento", Trim(Request.Form("Provin")))
		sBody = sBody & WriteLine("País", Trim(Request.Form("Pais")))
		sBody = sBody & WriteLine("Teléfono", Trim(Request.Form("Tel")))
		sBody = sBody & WriteLine("Fax", Trim(Request.Form("Fax")))
		sBody = sBody & WriteLine("Email", Trim(Request.Form("Mail")))
		sBody = sBody & WriteLine("Web", Trim(Request.Form("WebSite")))
		sBody = sBody & WriteLine("Representante Legal", Trim(Request.Form("Nombre")))
		sBody = sBody & WriteLine("DNI", Trim(Request.Form("DNI")))
		sBody = sBody & WriteLine("Fecha de Nacimiento", Trim(Request.Form("FechaNac")))
		sBody = sBody & WriteLine("Lugar de Nacimiento", Trim(Request.Form("PaisNac")))
		sBody = sBody & WriteLine("Cargo", Trim(Request.Form("Cargo")))
		sBody = sBody & WriteLine("Antigúedad", Trim(Request.Form("Anti")))
		sBody = sBody & WriteLine("Teléfono", Trim(Request.Form("TelContac")))
		sBody = sBody & WriteLine("Fax", Trim(Request.Form("FaxContac")))
		sBody = sBody & WriteLine("Email", Trim(Request.Form("MailContac")))
		sBody = sBody & WriteLine("Actividad en la Empresa", Trim(Request.Form("ActiEmpre")))
		sBody = sBody & WriteLine("Socio que lo presenta (1)", Trim(Request.Form("Socio1")))
		sBody = sBody & WriteLine("Socio que lo presenta (2)", Trim(Request.Form("Socio2")))
		sBody = sBody & WriteLine("Socio que lo presenta (3)", Trim(Request.Form("Socio3")))
	End If

	sBody = sBody & vbNewLine & vbNewLine _
	& "El siguiente formulario ha sido enviado en forma automática desde la Web." & vbNewLine _
	& FormatDateTime(Now(),1) & vbNewLine
	
	ArmarTexto = sBody

End Function

Function WriteLine(Etiqueta, Campo)
	If Etiqueta <> "" And Campo <> "" Then
		WriteLine = Etiqueta & ": " & ValStr(Campo) & vbNewLine
	End If
End Function

Function ValStr(Texto)
	If InStr(Texto, "@") <> 0 Or InStr(Texto, "www") <> 0 Then
		ValStr = Left(LCase(Texto),80)
	Else
		ValStr = Left(UCase(Texto),80)
	End If
End Function

%>